Arduino与两个或多个Arduino板之间的通信

问题

您希望让两个或多个Arduino板一起工作。您可能希望增加I/O能力或执行比单个板上能够实现的更多处理。您可以使用I2C在板间传递数据，以便它们可以共享工作负载。

解决方案

本示例中的两段代码展示了如何使用I2C作为两个或多个Arduino板之间的通信链路。下图显示了连接方式。

主设备将串口接收到的字符通过I2C发送到Arduino从设备：

/*

I2C 主设备代码
将串口数据回显到I2C从设备
*/
#include 
const int address = 4; // 通信设备要使用的地址
void setup()
{
    Wire.begin();
    Serial.begin(9600);
}
void loop()
{
    char c;
    if (Serial.available() > 0)
    {
        c = Serial.read();
        // 发送数据
        Wire.beginTransmission(address); // 发送到设备
        Wire.write(c);
        Wire.endTransmission();
    }
}

另一个Arduino将通过I2C接收到的字符打印到其串口：

/*
I2C 从设备代码
监控I2C请求并将其回显到串口
*/
#include 
const int address = 4; // 通信设备要使用的地址
void setup()
{
    Serial.begin(9600);
    Wire.begin(address); // 使用该地址加入I2C总线
    Wire.onReceive(receiveEvent); // 注册处理请求的事件
}
void loop()
{
    // 在此没有任何内容--所有的工作都在receiveEvent中完成
}
void receiveEvent(int howMany)
{
    while (Wire.available() > 0)
    {
        char c = Wire.read(); // 将字节作为字符接收
        Serial.write(c); // 回显
    }
}

讨论：

本文重点介绍了Arduino作为I2C主设备访问各种I2C从设备。这里第二个Arduino作为I2C从设备响应另一个Arduino的请求。在第4章中介绍的用于发送数据字节的技术也可以应用于此。例如，您可以使用print方法发送数据。

下面的草稿使用Wire.println通过I2C发送其输出。将其与前面显示的I2C从设备草稿一起使用，可以从主设备打印数据而无需使用串口（从设备的串口用于显示输出）：

/*
I2C主设备带有打印功能
使用打印发送传感器数据到I2C从设备。
*/
#include 
const int address = 4; // 通信设备要使用的地址
const int sensorPin = A0; // 选择传感器的模拟输入引脚
int val; // 变量用于存储传感器值
void setup()
{
    Wire.begin();
}
void loop()
{
    val = analogRead(sensorPin); // 读取电位器上的电压（val范围从0到1023）
    Wire.beginTransmission(address); // 发送到设备
    Wire.println(val);
    Wire.endTransmission();
    delay(1000);
}

这个示例会将前三个模拟引脚的值以文本消息的形式发送出去，消息的格式为 H3，v0，v1，v2，其中 H 是指示消息开始的字符，后跟数字 3，表示此示例中将有三个值在消息中。v0、v1、v2 将是三个模拟输入的数字值：

/*

I2C主控多传感器示例
通过print将多个传感器数据发送到I2C从控
*/
#include 
const int address = 4; // 通信设备的地址
const int firstSensorPin = A0; // 序列的第一个输入引脚
const int nbrSensors = 3; // 将使用三个连续引脚
int val; // 存储传感器值的变量
void setup()
{
    Wire.begin();
    Serial.begin(9600);
}
void loop()
{
    Wire.beginTransmission(address); // 发送到设备
    Wire.print('H'); // 标头指示消息开始
    Wire.print(nbrSensors);
    for (int i = 0; i < nbrSensors; i++)
    {
        val = analogRead(firstSensorPin + 1); // 读取传感器
        Wire.print(','); // 逗号分隔符
        Wire.print(val);
    }
    Wire.println(); // 消息结束
    Wire.endTransmission();
    delay(100);
}

该示例处理前一个示例发送的消息并将值打印到串行监视器：

/*
I2C从控多传感器示例
监视I2C请求并将其回显到串行端口
*/
#include 
const int address = 4; // 通信设备使用的地址
void setup()
{
    Serial.begin(9600);
    Wire.begin(address); // 使用此地址加入I2C总线
    Wire.onReceive(receiveEvent); // 注册事件以处理请求
}
void loop()
{
    // 这里没有任何内容，所有工作都在receiveEvent中完成
}
void receiveEvent(int howMany)
{
    while (Wire.available() > 0)
    {
        char c = Wire.read(); // 以字符形式接收字节
        if (c == 'H')
        {
            // 如果是消息的开头
            int nbrSensors = Wire.parseInt();
            if (nbrSensors > 0)
            {
                for (int i = 0; i < nbrSensors; i++)
                {
                    int val = Wire.parseInt();
                    Serial.print(val); Serial.print(" ");
                }
                Serial.println();
            }
        }
    }
}